str_replace() - String Replace without RegExp

I applaud you for trying, but that was one of the worst Perl programs I have ever seen. The general coding of *everything* is just horrible, for instance you are looping through the string letter by letter and checking if the following X letters match what you are looking for, when there is an index() function for that. You should just delete what you have written and upload the following text written by me:

use strict;
use warnings;

#
#    Function:
#    str_replace ( string search, string replace, string subject [, int count] )
#
#    Description:
#    This function returns a string or an array with all occurrences of
#    $search in $subject replaced with the given $replace value. If you
#    don't need fancy replacing rules (like regular expressions), you
#    should always use this function instead. Ported to Perl from PHP.
#
#    @PARAM $search String that you want to replace.
#    @PARAM $replace Replacement string.
#    @PARAM $subject The string that we are operating on.
#    @PARAM $count (optional) Limit the number of instances to replace.
#
#    Return values:
#    This function returns a string. Additionally, it returns -1
#    in case you forgot to provide the three basic parameters.
#
sub str_replace
{
  my $search = shift;							# what to find
  my $replace = shift;							# what to replace it with
  my $subject = shift;							# the scalar we are operating on
  if (! defined $subject) { return -1; }		# exit if all three required parameters are missing (!)
  my $count = shift;							# number of occurrences to replace
  if (! defined $count) { $count = -1; }		# set $count to -1 (infinite) if undefined

  # start iterating
  my ($i,$pos) = (0,0);
  while ( (my $idx = index( $subject, $search, $pos )) != -1 )	# find next index of $search, starting from our last position
  {
    substr( $subject, $idx, length($search) ) = $replace;		# replace $search with $replace

    $pos=$idx+length($replace);		# jump forward by the length of $replace as it may be
									# longer or shorter than $search was, and if we don't
									# compensate for this we end up in a different portion
									# of the string.

    if ($count>0 && ++$i>=$count) { last; }				# stop iterating if we have reached the limit ($count)
  }

  return $subject;
}

# This file has been over-commented so that beginners may understand it.
#For more help, see the examples at www.php.net/str_replace

For completeness sake, same code, formatted for pro's instead:

sub str_replace
{
	my $search = shift;
	my $replace = shift;
	my $subject = shift;
	if (! defined $subject) { return -1; }
	my $count = shift;
	if (! defined $count) { $count = -1; }
	
	my ($i,$pos) = (0,0);
	while ( (my $idx = index( $subject, $search, $pos )) != -1 )
	{
		substr( $subject, $idx, length($search) ) = $replace;
		$pos=$idx+length($replace);
		if ($count>0 && ++$i>=$count) { last; }
	}
	
	return $subject;
}

use Benchmark;

timethese(
	1000000,
	{
		'str_replace_1' => sub{
			my ($from, $to, $string) = ('Hello', 'Goodbye', 'Hello World');
			$string =~ s/$from/$to/;
			return $string;
		},
		'str_replace_2' => sub{
			my $replace_this = 'Hello';
			my $with_this  = 'Goodbye'; 
			my $string   = 'Hello World';
	
			my $length = length($string);
			my $target = length($replace_this);
	
			for(my $i=0; $i<$length - $target + 1; $i++) {
				if(substr($string,$i,$target) eq $replace_this) {
					$string = substr($string,0,$i) . $with_this . substr($string,$i+$target);
					return $string; #Comment this if you what a global replace
				}
			}
			return $string;
		},
		'str_replace_3' => sub{
			my $search = 'Hello';
			my $replace = 'Goodbye';
			my $subject = 'Hello World';
			if (! defined $subject) { return -1; }
			my $count = -1;
			if (! defined $count) { $count = -1; }
	
			my ($i,$pos) = (0,0);
			while ( (my $idx = index( $subject, $search, $pos )) != -1 ){
				substr( $subject, $idx, length($search) ) = $replace;
				$pos=$idx+length($replace);
				if ($count>0 && ++$i>=$count) { last; }
			}
	
			return $subject;
		}
	}
);